| View previous topic :: View next topic |
| Author |
Message |
X-Tools
Valued Contributor
Joined: 20 Sep 2001
Posts: 296
Location: Germany
|
 Posted: Mon Aug 09, 2004 2:34 pm Post subject: Invisible / Transparen Group element |
 |
|
Hi,
does somebody know a way to make a group element real transparent / invisible. I want the border lines to be invisible to.
I thought about using the group-element features (moving moves all child elements too), but I dont want to see these lines on the dialog I am building at the moment.
Thanks for your help.
Bye, Fabian |
|
| Back to top |
|
 |
Skit3000
Admin Team
Joined: 11 May 2002
Posts: 2166
Location: The Netherlands
|
| Posted: Mon Aug 09, 2004 2:43 pm Post subject: |
|
|
Maybe you can make your own function to simulate an invisible group element? This could be a little example of how to do it... 
| Code: | #define command,group
DIALOG CREATE,Nieuw Dialoog,-1,0,240,160
REM *** Gewijzigd door de Dialoog Ontwerper op 9-8-2004 - 16:37 ***
DIALOG ADD,BUTTON,BUTTON1,20,60,65,25,BUTTON1
DIALOG ADD,BUTTON,BUTTON2,50,60,65,25,BUTTON2
DIALOG ADD,BUTTON,BUTTON3,80,60,65,25,BUTTON3
DIALOG SHOW
group add,BUTTON1
group add,BUTTON2
group add,BUTTON3
wait event
group move,down,30
wait 1
exit
:group
if @equal(%1,"ADD")
%%groups = @trim(%%groups)@cr()%2@cr()
end
if @equal(%1,"MOVE")
if @equal(%2,"DOWN")
%%temp = %%groups
repeat
if @unequal(@trim(%%temp),)
%%tempdlgitem = @substr(%%temp,1,@pred(@pos(@cr(),%%temp)))
dialog setpos,%%tempdlgitem,@sum(@dlgpos(%%tempdlgitem,T),%3)
end
%%temp = @strdel(%%temp,1,@pos(@cr(),%%temp))
until @equal(%%temp,)
end
end
exit |
_________________
[ Add autocomplete functionality to your VDS IDE windows! ]
Voor Nederlandse beginners met VDS: bekijk ook eens deze tutorial! |
|
| Back to top |
|
|
vdsalchemist
Admin Team
Joined: 23 Oct 2001
Posts: 1448
Location: Florida, USA
|
| Posted: Mon Aug 09, 2004 3:26 pm Post subject: |
|
|
X-Tools,
You could simply place a gradient control over all of the group box like the code below.
| Code: | REM ****************************************************
REM propties.dsc v. 4.0
REM use of TAB dialog element
REM (c) 1995 - 2003 Commercial Research Ltd
title Property Pages
gosub getdata
OPTION SCALE,96
DIALOG CREATE,Properties,-1,0,354,232
REM *** Modified by Dialog Designer on 8/9/2004 - 11:17 ***
DIALOG ADD,TAB,TAB1,4,6,340,186,Tab 1|Tab 2|Tab 3
DIALOG ADD,BUTTON,OK,200,120,72,24,
DIALOG ADD,BUTTON,Cancel,200,192,72,24,Cancel
DIALOG ADD,BUTTON,Apply,200,274,72,24,Apply
DIALOG ADD,GROUP,GROUP1,31,15,320,148
DIALOG ADD,GRADIENT,GRADIENT1,31,15,320,148,$00C8D0D4,$00C8D0D4,,BOTTOMTOTOP
DIALOG SHOW
if @not(%1)
REM allow initial tab to be specified on command-line
%1 = Tab 1
gosub %1OPEN
end
:evloop
wait event
%E = @event()
goto %E
:Tab 1CLICK
:Tab 2CLICK
:Tab 3CLICK
%2 = @substr(%E,1,-5)
gosub %1CLOSE
shift
gosub %1OPEN
goto evloop
:ApplyBUTTON
gosub savedata
goto evloop
:OKBUTTON
gosub savedata
:CancelBUTTON
:CLOSE
exit
:Tab 1OPEN
rem DIALOG SET,GROUP1," Properties page 1 "
DIALOG ADD,TEXT,TEXT2,54,24,,,Name:
DIALOG ADD,EDIT,EDIT1,52,68,240,19,%%name
DIALOG ADD,TEXT,TEXT3,80,24,,,Address:
DIALOG ADD,EDIT,EDIT2,78,68,240,90,%%address,MULTI,TABS
exit
:Tab 2OPEN
rem DIALOG SET,GROUP1," Properties page 2 "
DIALOG ADD,CHECK,CHECK1,52,68,180,18,Use Email?,%%use
DIALOG ADD,TEXT,TEXT2,80,24,,,Email:
DIALOG ADD,EDIT,EDIT1,78,68,240,19,%%email
exit
:Tab 3OPEN
rem DIALOG SET,GROUP1," Properties page 3 "
DIALOG ADD,CHECK,CHECK1,48,48,180,18,Other Stuff 1,%%other1
DIALOG ADD,CHECK,CHECK2,72,48,180,18,Other Stuff 2,%%other2
DIALOG ADD,CHECK,CHECK3,96,48,180,18,Other Stuff 3,%%other3
DIALOG ADD,CHECK,CHECK4,120,48,180,18,Other Stuff 4,%%other4
exit
:Tab 1CLOSE
%%name = @dlgtext(EDIT1)
%%address = @dlgtext(EDIT2)
DIALOG REMOVE,TEXT2
DIALOG REMOVE,EDIT1
DIALOG REMOVE,TEXT3
DIALOG REMOVE,EDIT2
exit
:Tab 2CLOSE
%%use = @dlgtext(CHECK1)
%%email = @dlgtext(EDIT1)
DIALOG REMOVE,CHECK1
DIALOG REMOVE,TEXT2
DIALOG REMOVE,EDIT1
exit
:Tab 3CLOSE
%%other1 = @dlgtext(CHECK1)
%%other2 = @dlgtext(CHECK2)
%%other3 = @dlgtext(CHECK3)
%%other4 = @dlgtext(CHECK4)
DIALOG REMOVE,CHECK1
DIALOG REMOVE,CHECK2
DIALOG REMOVE,CHECK3
DIALOG REMOVE,CHECK4
exit
:getdata
REM in a real example this data would probably be
REM got from the registry
%%name =
%%address =
%%use =
%%email =
exit
:savedata
REM this subroutine does nothing.
REM it is run when OK or Apply are clicked.
REM in a real example it would probably save the data
REM to the Registry.
exit
|
_________________
Home of
Give VDS a new purpose!
 |
|
| Back to top |
|
|
X-Tools
Valued Contributor
Joined: 20 Sep 2001
Posts: 296
Location: Germany
|
| Posted: Mon Aug 09, 2004 3:57 pm Post subject: |
|
|
Thanks for your ideas  |
|
| Back to top |
|
|
|
|
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You can attach files in this forum
You can download files in this forum
|
|
FAQ
Search
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
@vdsworld